#!/usr/bin/mawk -We
# *********************************************************************
# repairtable: append missing trailing tabs to table rows; truncate
# records that contain extra-fields with rispect to the table header.
#
# Copyright (c) 1998,2006 Carlo Strozzi
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; version 2 dated June, 1991.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#
# *********************************************************************
# $Id: repairtable,v 1.3 2006/03/10 11:26:13 carlo Exp $

BEGIN {
  NULL = ""; FS = OFS = "\t"

  # Get local settings.
  nosql_install = ENVIRON["NOSQL_INSTALL"]
  stdout = ENVIRON["NOSQL_STDOUT"]
  stderr = ENVIRON["NOSQL_STDERR"]

  # Set default values if necessary.
  if (nosql_install == NULL) nosql_install = "/usr/local/nosql"
  if (stdout == NULL) stdout = "/dev/stdout"
  if (stderr == NULL) stderr = "/dev/stderr"

  while (ARGV[++i] != NULL) {
    if (ARGV[i] == "-F" || ARGV[i] == "--filler") filler = ARGV[++i]
    else if (ARGV[i] == "-v" || ARGV[i] == "--verbose") verbose = 1
    else if (ARGV[i] == "-h" || ARGV[i] == "--help") {
       system("grep -v '^#' " nosql_install "/help/repairtable.txt")
       exit(rc=1)
    }
    else if (ARGV[i] == "--show-copying") {
       system("cat " nosql_install "/doc/COPYING")
       exit(rc=1)
    }
    else if (ARGV[i] == "--show-warranty") {
       system("cat " nosql_install "/doc/WARRANTY")
       exit(rc=1)
    }
  }

  ARGC = 1					# Fix argv[]
}

#
# Main loop
#

# Column names.
NR == 1 {
  num_cols = NF
  gsub(/[\001 ]+/,"")				# remove SOH and blanks
  printf("\001"); gsub(/\t/,"\t\001")
  print; next
}

# Table body.
{
  if (NF == num_cols) { print; next }

  if (NF < num_cols) {
    printf("%s", $0)
    NF == 0 ? num_tabs = num_cols - 1 : num_tabs = num_cols
    for (i = NF+1; i <= num_tabs; i++) printf("\t%s", filler)
  } else {
    for (i = 1; i < num_cols; i++) printf("%s\t", $i)
    printf("%s", $i)
    if (verbose)
      print "repairtable: record " NR - 2 " was truncated !" > stderr
    rc = 1
  }
  printf("\n")
}

END { exit(rc) }

# End of program.
