#!/usr/bin/mawk -We
# *********************************************************************
# tabletordb: convert a NoSQL table into /rdb format.
#
# Copyright (c) 2003,2006 Carlo Strozzi
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; version 2 dated June, 1991.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#
# *********************************************************************
# $Id: tabletordb,v 1.3 2006/03/10 11:26:13 carlo Exp $

BEGIN {
  NULL = "" ;  FS = OFS = "\t"

  # Get local settings.
  nosql_install = ENVIRON["NOSQL_INSTALL"]
  stdout = ENVIRON["NOSQL_STDOUT"]
  stderr = ENVIRON["NOSQL_STDERR"]

  # Set default values if necessary.
  if (nosql_install == NULL) nosql_install = "/usr/local/nosql"
  if (stdout == NULL) stdout = "/dev/stdout"
  if (stderr == NULL) stderr = "/dev/stderr"

  while (ARGV[++i] != NULL) {
    if (ARGV[i] == "-i" || ARGV[i] == "--input") i_file = ARGV[++i]
    else if (ARGV[i] == "-o" || ARGV[i] == "--output") o_file = ARGV[++i]
    else if (ARGV[i] == "-r" || ARGV[i] == "--crlf") cr = 1
    else if (ARGV[i] == "-n" || ARGV[i] == "--no-dashline") nd = 1
    else if (ARGV[i] == "-h" || ARGV[i] == "--help") {
       system("grep -v '^#' " nosql_install "/help/tabletordb.txt")
       exit(rc=1)
    }
    else if (ARGV[i] == "--show-copying") {
       system("cat " nosql_install "/doc/COPYING")
       exit(rc=1)
    }
    else if (ARGV[i] == "--show-warranty") {
       system("cat " nosql_install "/doc/WARRANTY")
       exit(rc=1)
    }
  }

  ARGC = 1					# Fix argv[]

  if (o_file == NULL) o_file = stdout
  if (i_file != NULL) { ARGV[1] = i_file; ARGC = 2 }
}

# Main loop                                                                     

# Convert table header.
NR == 1 {

   gsub(/\001/, "")		# remove SOH markers
   gsub(/ +/, "")		# trim blanks in names
   print > o_file		# column names
   if (!nd) {
      gsub(/[^\t]/, "-")	# dash line
      print > o_file
   }
   next
}

{ gsub(/ +\t/,"\t"); sub(/ +$/,NULL) }	# trim trailing blanks.

cr { $0 = $0 "\r" }		# add trailing CR if required.

{ print > o_file }		# table body

# End of program.
